« Perl Weekly Challenge 180. Perl Weekly Challenge 182. »

Perl Weekly Challenge 181.

My solutions (task 1 and task 2 ) to the The Weekly Challenge - 181.

Task 1: Sentence Order

Submitted by: Mohammad S Anwar
You are given a paragraph.

Write a script to order each sentence alphanumerically and
print the whole paragraph.

Example
Input:

    All he could think about was how it would all end. There was
    still a bit of uncertainty in the equation, but the basics
    were there for anyone to see. No matter how much he tried to
    see the positive, it wasn't anywhere to be seen. The end was
    coming and it wasn't going to be pretty.

Ouput:
    about All all could end he how it think was would. a anyone
    basics bit but equation, for in of see still the the There
    there to uncertainty was were. anywhere be he how it matter
    much No positive, see seen the to to tried wasn't. and be
    coming end going it pretty The to was wasn't.

To solve the problem I read the whole file, separate into sentences by splitting on ‘.’, split on space, order alphanumerically and join, sticking in the end-of-sentence ‘.’. This fits comfortably into a oneliner.

perl -n -000 -E '
chomp; say ((join " ",  sort {fc $a cmp fc $b} split " ").". ") for split /\./;  say "";
' <<EOF |fmt
    All he could think about was how it would all end. There was
    still a bit of uncertainty in the equation, but the basics
    were there for anyone to see. No matter how much he tried to
    see the positive, it wasn't anywhere to be seen. The end was
    coming and it wasn't going to be pretty.

    It all started with the computer. Had he known what was to
    follow, he would have never logged on that day. But the truth
    was there was no way to know what was about to happen. So Dave
    pressed the start button, the computer booted up, the screen
    came alive, and everything Dave knew to be true no longer was.
EOF

(2nd paragraph taken from here). I used the -000 flag to split the input into paragraphs, so that I can arrange longer texts, and -n to implicitly loop over them. Each paragraph is split into sentences, reordered normalizing with the fc function before comparing strings, so that ‘Z’ doesn’t come before ‘a’. The results are:

about All all could end he how it think was would.  a anyone basics bit
but equation, for in of see still the the There there to uncertainty
was were.  anywhere be he how it matter much No positive, see seen the
to to tried wasn't.  and be coming end going it pretty The to was wasn't.

all computer It started the with.  day follow, Had have he he known
logged never on that to was what would.  about But happen know no the
there to to truth was was was way what.  alive, and be booted button,
came computer Dave Dave everything knew longer no pressed screen So
start the the the to true up, was.

The full code is

# Perl weekly challenge 181
# Task 1: Sentence order
#
# See https://wlmb.github.io/2022/09/05/PWC181/#task-1-sentence-order
use v5.36;
use Text::Wrap qw(wrap $columns $break);
$columns=62; $break=qr/\s/;
local $/ = ""; # paragraph mode
while(<>){ # for each paragraph
    chomp; # remove trailing newlines
    my @output;
    foreach(split /\./){ # For each sentence. Assume ends in "."
	my @words = split " "; # Separate into words. Assume a space even after punctuation.
	my @sorted_words = sort {fc $a cmp fc $b} @words;
	push @output, join(" ",  @sorted_words) . ". "; # join words and add ending "."
    }
    say wrap('', '', (join " ", @output), "\n");
}

Example:

./ch-1.pl <<EOF
    All he could think about was how it would all end. There was
    still a bit of uncertainty in the equation, but the basics
    were there for anyone to see. No matter how much he tried to
    see the positive, it wasn't anywhere to be seen. The end was
    coming and it wasn't going to be pretty.

    It all started with the computer. Had he known what was to
    follow, he would have never logged on that day. But the truth
    was there was no way to know what was about to happen. So Dave
    pressed the start button, the computer booted up, the screen
    came alive, and everything Dave knew to be true no longer was.
EOF

Results:

about All all could end he how it think was would.  a anyone
basics bit but equation, for in of see still the the There
there to uncertainty was were.	anywhere be he how it matter
much No positive, see seen the to to tried wasn't.  and be
coming end going it pretty The to was wasn't.

all computer It started the with.  day follow, Had have he he
known logged never on that to was what would.  about But
happen know no the there to to truth was was was way what.
alive, and be booted button, came computer Dave Dave
everything knew longer no pressed screen So start the the the
to true up, was.

Task 2: Hot Day

Submitted by: Mohammad S Anwar
You are given file with daily temperature record in random
order.

Write a script to find out days hotter than previous day.

Example
Input File: (temperature.txt)

2022-08-01, 20
2022-08-09, 10
2022-08-03, 19
2022-08-06, 24
2022-08-05, 22
2022-08-10, 28
2022-08-07, 20
2022-08-04, 18
2022-08-08, 21
2022-08-02, 25

Output:
2022-08-02
2022-08-05
2022-08-06
2022-08-08
2022-08-10

I can read the input into a hash, sort the keys and then compare temperatures. Assuming there are no holes in the table the problem may be solved with a 3-liner.

perl -MList::MoreUtils=pairwise -n -E '
BEGIN{sub dc($p, $q){@p=split "-",$p; @q=split "-",$q;@c=pairwise {$a<=>$b} @p,@q;
for(0..2){return $c[$_] if $c[$_]} 0}} chomp; ($d,$t)=split ", "; $t{$d}=$t;
END {@d=sort {dc($a, $b)} keys %t; for(1..@d-1){say $d[$_] if $t{$d[$_]}>$t{$d[$_-1]}}}
' <<EOF
2022-08-01, 20
2022-08-09, 10
2022-08-03, 19
2022-08-06, 24
2022-08-05, 22
2022-08-10, 28
2022-08-07, 20
2022-08-04, 18
2022-08-08, 21
2022-08-02, 25
EOF

Results:

I test it with dates that cross month and year boundaries

perl -MList::MoreUtils=pairwise -n -E '
BEGIN{sub dc($p, $q){@p=split "-",$p; @q=split "-",$q;@c=pairwise {$a<=>$b} @p,@q;
for(0..2){return $c[$_] if $c[$_]} 0}} chomp; ($d,$t)=split ", "; $t{$d}=$t;
END {@d=sort {dc($a, $b)} keys %t; for(1..@d-1){say $d[$_] if $t{$d[$_]}>$t{$d[$_-1]}}}
' <<EOF
2022-12-31, 20
2023-01-08, 10
2023-01-02, 19
2023-01-05, 24
2023-01-04, 22
2023-01-09, 28
2023-01-06, 20
2023-01-03, 18
2023-01-07, 21
2023-01-01, 25
EOF

Results:

For the full code I use the DateTime and Date::Parse modules to compare dates and add some checks for invalid and missing dates.

# Perl weekly challenge 181
# Task 2: Hot day
#
# See https://wlmb.github.io/2022/09/05/PWC181/#task-2-hot-day
use v5.36;
use List::MoreUtils qw(pairwise);
use Date::Parse;
use DateTime;
 9
my %temps;
while(<>){ # Input data from standard input in format YYYY-MM-DD, Temp
    chomp;
    my ($date, $temp)=split ", ";
    $temps{$date}=$temp;
}
my %datetimes;
for(keys %temps){ # check valid dates
    die "Wrong date $_" unless defined (my $time=str2time($_));
    $datetimes{$_}=DateTime->from_epoch($time); # Build DateTime object
}
my @sorted=sort {DateTime->compare($datetimes{$a}, $datetimes{$b})} keys %temps;
for(1..@sorted-1){
    die "Dates not consecutive"
        unless $datetimes{$sorted[$_]}->delta_days($datetimes{$sorted[$_-1]})->days==1;
    say $sorted[$_] if $temps{$sorted[$_]}>$temps{$sorted[$_-1]}
}
27
28
29

Example:

./ch-2.pl <<EOF
2022-08-01, 20
2022-08-09, 10
2022-08-03, 19
2022-08-06, 24
2022-08-05, 22
2022-08-10, 28
2022-08-07, 20
2022-08-04, 18
2022-08-08, 21
2022-08-02, 25
EOF

Results:

Written on September 5, 2022